Suche Programm zum speziellen entpacken!

Dieses Thema im Forum "Windows XP / Server 2003/2008 / Vista" wurde erstellt von Pummel, 19. November 2005.

Status des Themas:
Es sind keine weiteren Antworten möglich.
  1. Pummel

    Pummel Kbyte

    Registriert seit:
    9. April 2004
    Beiträge:
    337
    Hallo
    Ich glaube ich bin auf der Suche nach etwas das es nicht gibt aber egal:
    Ich habe sehr viele zip-Archive auf meinem PC, die ich noch nicht entpackt hab. Leider haben die Dateien in den Archiven total unpraktische Namen und heißen nicht so, wie das Archiv heißt. Jetzt muss ich immer ein Archiv entpacken, den Namen kopieren, die entpackte Datei umbenennen und das Archiv löschen. Und das würde bei allen Archiven sehr lange dauern.
    Gibt es ein Programm oder Tool oder was weiß ich was diese Arbeit erledigen könnte?
    Vielen Dank
    MfG Philipp
     
  2. Michi0815

    Michi0815 Guest

    Registriert seit:
    7. Januar 2004
    Beiträge:
    3.429
    ist in jedem archiv immer nur 1 datei, welchen packer und welches betriebssystem hast du?
     
  3. Pummel

    Pummel Kbyte

    Registriert seit:
    9. April 2004
    Beiträge:
    337
    Ich habe Windows XP Home Edition, benutze WinRAR und in jedem Archiv ist immer nur eine Datei.
     
  4. Michi0815

    Michi0815 Guest

    Registriert seit:
    7. Januar 2004
    Beiträge:
    3.429
    alle .zip in einen ordner (sicherheitshalber noch sicherheitskopien woanders hinkopieren), die extract.bat dazu packen und dann noch einen doppelklick...

    extract.bat
    Code:
    @echo off
    
    if %1.==. goto main
    goto %1
    
    :main
    md Archiv
    for %%f in (*.zip) do @%0 loop %%f
    goto ende
    
    :loop
    md tmp
    move %2 tmp
    cd tmp
    <vollständiger\pfad\zu>\winrar.exe e -o+ %~nx2
    cd ..
    move tmp\%~nx2 Archiv
    for %%f in (tmp\*) do @move %%f %~dpn2%%~xf
    rd tmp
    goto ende
    
    :ende
     
  5. Pummel

    Pummel Kbyte

    Registriert seit:
    9. April 2004
    Beiträge:
    337
    Ok vielen dank! Aber irgend wie klappt das noch nicht ganz bei mir.
    Ich habe beispielhalber mal einen Ordner genommen, 5 Archive rein kopiert, eine extract.bat erstellt und diesen Code reinkopiert:
    @echo off

    if %1.==. goto main
    goto %1

    :main
    md Archiv
    for %%f in (*.zip) do @%0 loop %%f
    goto ende

    :loop
    md tmp
    move %2 tmp
    cd tmp
    C:\Programme\WinRAR\winrar.exe e -o+ %~nx2
    cd ..
    move tmp\%~nx2 Archiv
    for %%f in (tmp\*) do @move %%f %~dpn2%%~xf
    rd tmp
    goto ende

    :ende

    Wenn ich jetzt die Datei starte, kommt jetzt 5 mal:
    Keine Archive gefunden und es beendet sich wieder. Nun habe ich dort bei den Archiven einen neuen Ordner (Archive), in dem allerdings nichts drin ist.
    Habe ich was falsch gemacht?
     
  6. Michi0815

    Michi0815 Guest

    Registriert seit:
    7. Januar 2004
    Beiträge:
    3.429
    lass mich raten: es sind leerzeichen im pfad/dateinamen? :rolleyes:
     
  7. Michi0815

    Michi0815 Guest

    Registriert seit:
    7. Januar 2004
    Beiträge:
    3.429
    Code:
    @echo off
    
    if %1.==. goto main
    goto %1
    
    :main
    md Archiv
    for %%f in (*.zip) do @%0 loop "%%f"
    goto ende
    
    :loop
    md tmp
    move "%2" tmp
    cd tmp
    C:\Programme\WinRAR\winrar.exe e -o+ "%~nx2"
    cd ..
    move "tmp\%~nx2" Archiv
    for %%f in (tmp\*) do @move "%%f" "%~dpn2%%~xf"
    rd tmp
    goto ende
    
    :ende
     
  8. Pummel

    Pummel Kbyte

    Registriert seit:
    9. April 2004
    Beiträge:
    337
    Mh jetzt kommt immer die Meldung:
    Syntaxfehler. Das System kann die angegebene Datei nicht finden.
    Und es kommt noch die Warnung: Keine Archive gefunden.
     
  9. Pummel

    Pummel Kbyte

    Registriert seit:
    9. April 2004
    Beiträge:
    337
    Mache ich irgend was falsch?
     
  10. Michi0815

    Michi0815 Guest

    Registriert seit:
    7. Januar 2004
    Beiträge:
    3.429
    seltsam....

    gib mal ein paar infos: wie heisst das typische archiv und die datei darin, funktioniert winrar prinzipiell (=was passiert wenn du C:\Programme\WinRAR\winrar.exe e -o+ <ein archiv> in der kommandozeile eingibst).
    was passiert wenn du
    Code:
    @echo off
    
    if %1.==. goto main
    goto %1
    
    :main
    for %%f in (*.zip) do @%0 loop "%%f"
    goto ende
    
    :loop
    echo Archiv: "%2"
    md tmp
    move "%2" tmp
    cd tmp
    echo Entpacke: "%~nx2"
    C:\Programme\WinRAR\winrar.exe e -o+ "%~nx2"
    cd ..
    for %%f in (tmp\*) do @echo Datei: "%%f" Ziel: "%~dpn2%%~xf"
    goto ende
    
    :ende
    auf ein archiv ansetzt?
     
  11. Pummel

    Pummel Kbyte

    Registriert seit:
    9. April 2004
    Beiträge:
    337
    Also als Beispiel heißt jetzt ein Archiv "man u goals.zip"
    und die Datei darin "g7wko7kdqyo0.avi".
    Wenn ich den oben genannten Code für ein Archiv benutze kommt dies hier:

    [​IMG]


    Normal funktioniert WinRAR einwandfrei.
    Vielleicht hilft das weiter: Ich habe WinRAR 3.5 und nur die 40 Tage Testversion und immer wenn ich WinRAR öffne kommt eine Nachricht das ich die Lizenz kaufen soll.

    Und wenn ich "C:\Programme\WinRAR\winrar.exe e -o+ <ein archiv>" eingeben soll, wo soll sich das Archiv befinden?
    Wenn ich zB "C:\Programme\WinRAR\winrar.exe e -o+ man u goals.zip" eingebe und das Archiv zu dem WinRAR Verzeichnis hinzufüge kommt wieder die nachricht " kein archiv gefunden".
     
  12. Michi0815

    Michi0815 Guest

    Registriert seit:
    7. Januar 2004
    Beiträge:
    3.429
    war nur ein satz "" zu viel :rolleyes:

    das hier hat bei mir funktioniert:
    Code:
    @echo off
    
    if %1.==. goto main
    goto %1
    
    :main
    md Archiv
    for %%f in (*.zip) do @%0 loop "%%f"
    goto ende
    
    :loop
    md tmp
    move %2 tmp
    cd tmp
    C:\Programme\WinRAR\winrar.exe e -o+ "%~nx2"
    cd ..
    move "tmp\%~nx2" Archiv
    for %%f in (tmp\*) do @move "%%f" "%~dpn2%%~xf"
    rd tmp
    goto ende
    
    :ende
     
  13. Pummel

    Pummel Kbyte

    Registriert seit:
    9. April 2004
    Beiträge:
    337
    Vielen vielen Dank!
    Du weißt gar nicht wie viel du mir damit geholfen hast!
    Dickes Merci!!!
     
Status des Themas:
Es sind keine weiteren Antworten möglich.

Diese Seite empfehlen