Excel: Nur bestimmte Werte addieren

Hallo,

ich habe folgendes Anliegen bei Excel:
Ich habe eine Tabelle erstellt, in der in der einen Spalte das Datum, in der nächsten die Einnahmen und in der anderen der Grund stehen. Diese zu addieren ist so weit kein Problem, ich würde aber gerne das ganze so erweitern, dass auf einer anderen Seite eine Zelle die Einnahmen einer bestimmten "Sorte" und eines bestimmten Monats enthält.
Also: Ich schreibe auf der "Hauptseite" fortlaufend
01.01.08 10 EUR Getränke (Cola)
03.01.08 15 EUR Speisen
07.01.08 19 EUR Getränke (Fanta)
09.01.08 17 EUR Getränke (Wasser)
usw.

und auf der zweiten Seite hätte ich gern eine Zelle die alle Einnahmen des Monats Januar 2008 aus Getränkeverkäufen enthält! Erschwerend kommt hinzu, dass die Einträge nicht eindeutig sind, z. B. einmal Getränke (Wasser) das andere mal Getränke "Cola". Das Wort "Getränke" steht aber immer dabei.
Wie stelle ich das an?
Danke im voraus!

 

Code:

=SUMMEWENN(C1:C4;"Getränke*";B1:B4)

In den Zellen C1:C4 ist der Text, in B1:B4 ist der Betrag. * nach Getränke bedeutet, es kann noch etwas nach Getränke stehen.

Gruss
Bruno

 

Darin wird aber nicht der Zeitraum bedacht, wie wäre es mit einer dynamischen Tabelle?

 

Das war ja Gedankenübertragung!
Ich hab das so gemacht, wie angegeben und das funktioniert so, wie ichs mir vorgestellt habe, bis auf den Zeitraum eben! Deshalb meine Frage: Was ist denn eine dynamische Tabelle?

 

Ich dachte, Du hättest die Beträge nach Datum sortiert, und könntest deshalb den Bereich manuell eingeben.

Eine dynamische Tabelle ist eine, die selber merkt, dass neue Werte hinzugekommen sind. (Oder so ähnlich.)

Zur Summe mit mehr als einer Bedingung habe ich diesen Link gefunden: http://www.excelformeln.de/formeln.html?welcher=61

Nachtrag: zur dynamischen Tabelle habe ich auch noch einen Link: http://www.excelformeln.de/formeln.html?welcher=221

Gruss
Bruno

 

Hi,

{{=SUMME((MONAT(A1:A100)=2)*(TEIL(C1:C100;1;8)="Getränke")*B1:B100)}

Geschweifte Klammer nicht mit eingeben, sondern Formel mit Strg+Shift+Enter abschließen.

 

Ok, jetzt kommt der Punkt, den ihr Profis wohl alle hasst
Habe es in der Form eingegeben:

=SUMME(WENN(MONAT(Liste!A5:A700)=1;WENN(Liste!C5:C700="*Getränke*";Liste!B5:B700)))

kommt aber nur "0" bei raus. Ich vermute als Laie es liegt am Datum, dass ich im Format dd.mm.yyyy angebe. Was ist denn da in der Formel Januar?

PS: "Liste" ise die erste Seite, die Tabelle für Monate steht auf der 2. Seite!

 

Hi,

das liegt nicht am Zellformat, sondern an deiner Formel. Vergleiche sie einmal genau mit meiner.
Januar ist die =1 in diesem Formelteil: MONAT(Liste!A5:A700)=1

 

Ja gut, deine Formel hat einen ganz anderen Aufbau als meine! Aber das liegt daran, dass ich schon vorher die von brums erstem Link genommen habe (http://www.excelformeln.de/formeln.html?welcher=61). Funktioniert das nicht? Da sind nämlich mehrere Möglichkeiten gegeben, aber es steht auch dabei, dass man nur die erste (also die, die ich genommen habe) bei Datumsselektion nutzen kann!

@Beverly: Ws bedeuten bei dir die "*"s und "TEIL"? Das taucht in der anderen gar nicht auf! Und wozu ist das "1;8"?

 

Danke, aber 2 Fragen hab ich noch:

Sollte ich also "*Getränke*" schreiben, müssen die Parameter 1 und 10 lauten, richtig?
Nächste Frage: Wieso steht denn dann vor dem "B1:B100" auch ein Mal? Das ist doch das zu Multiplizierende und keine Bedingung, oder?

 

Beverly hat hier überprüft, ob der Monat in Spalte A Februar (=2) ist. Dann wird ein Teil der Spalte C (8 Zeichen beginnend mit Position 1) überprüft, ob da "Getränke" steht. Wenn die Bedingung erfüllt ist, ist die Rückgabe 1, wenn nicht ist die Rückgabe 0. Eine Multiplikation mit 0 hat das Ergebnis 0. Es müssen also beide Bedinungen erfüllt sein, um "1 * 1 * Betrag" als Rückgabe zu erhalten (hier sind die * das Malzeichen).

(Die * als Wildcards kannst Du nur bei bestimmten Funktionen verwenden (wie z. B. SUMMEWENN). Hier geht es aber nicht.)

Nochmals in Kürze: Die angepasste Formel für Dich für Januar mit Shift+Ctrl+Enter eingeben (wegen dem Array).

Code:

=SUMME((MONAT(Liste!A5:A700)=1)*(TEIL(Liste!C5:C700;1;8)="Getränke")*Liste!B5:B700)

Gruss
Bruno

 

Ist es auch möglich das so einzurichten, dass das Wort Getränke oder ein beliebig anderes nicht an erster Stelle steht, sondern irgendwo im Textfeld?

Ich weiß zwar nicht, was du mit "Wildcards" gemeint hast, aber ich denke du meinst damit "*Getränke*", weil das nicht geht. Geht es irgendwie anders?

 

Wenn ich fragen darf, wieso fügst du keine Spalte ein, die den Typ (Speise, Getränk, usw.) bestimmt, und dann kannst in der 4 Spalte detailliertere Angaben (coke,fanta, Chips, sandwich, usw.) machen, damit erleichterst du dir die Arbeit ziemlich und kannst so auch noch weitere Statistiken erstellen....

@brum
Ich habe das Excel2007 auf spanisch, und finde diese TEIL-Funktion nicht. In welcher Kategorie muss ich suchen? Thx

 

...ist unter Text zu finden.

Ich habe nun den Teil mit TEIL durch die Funktion SUCHEN ersetzt (falls Gross-/Kleinschreibung beachtet werden sollen, kannst Du auch FINDEN verwenden):

Code:

=SUMME((MONAT(Liste!A5:A700)=1)*(NICHT(ISTFEHLER(SUCHEN("Getränke";Liste!C5:C700))))*Liste!B5:B700)

Und: Wildcard

Gruss
Bruno

 

Klar darfst du fragen ;-)
Ich will das in eine Tabelle einbauen, die ich selbst nicht erstellt habe und bei der ich mich bei den Formeln nicht auskenne... Is zwar weit weniger kompliziert, als das was ich jetzt hier gebastelt bekommen hab, aber ich will da jetzt nicht zu weit ausholen... und so geht es ja hoffentlich auch!

Juhu, jetzt geht es :-) Vielen Dank!
2 kleine Punkte vielleicht noch:
- Wie kann ich zusätzlich zum Monat noch das Jahr berücksichtigen?
- Was bedeutet der Teil NICHT(ISTFEHLER( ?

 

Wenn SUCHEN nichts findet, gibt es einen Fehler. Da ich aber nicht "nichts" will, sondern wenn es enthalten ist, kehre ich das mit NICHT um (wenn kein Fehler entsteht).

Wenn Du zusätzlich noch das Jahr willst, kannst Du das zusätzlich multiplizieren:

Code:

=SUMME([B](JAHR(Liste!A5:A700)=2008)*[/B](MONAT(Liste!A5:A700)=1)*(NICHT(ISTFEHLER(SUCHEN("Getränke";Liste!C5:C700))))*Liste!B5:B700)

Gruss
Bruno

 

So, inzwischen habe ich mich doch entschieden benni-spains Vorschlag zu übernehmen und bin am Umbauen! Allerdings habe ich ein kleines Problem:
Ich möchte Jahr (2007,2008...) und Monat (1-12) aus 2 Spalten links vom "Formelkästchen" in die Formel übernehmen. Wenn ich aber statt 2008 nur B4 oder so schreibe funktioniert die Formel aber nicht. Was muss ich tun, damit ich einfach die Formeln "nach unten ziehen" kann und nicht in jeder Zeile manuell Monat und Jahr eintippen muss?

 

Klaro, aber das ist gut so

Die Sache mit den Monaten scheint so weit zu funktionieren, danke! Allerdings hat sich jetzt ein anderes Problem ergeben:
Wenn ich mit der "alten" Formel

Code:

=SUMME((JAHR(Liste!A5:A700)=2008)*(MONAT(Liste!A5:A700)=1)*(NICHT(ISTFEHLER(SUCHEN("Getränke";Liste!C5:C700))))*Liste!B5:B700)

arbeite, aber eine Kategorie N und die andere NO nenne, dann gibt er mir bei N auch alle Werte der NO Kategorie an.

Code:

=SUMME((MONAT(A1:A100)=2)*(TEIL(C1:C100;1;8)="Getränke")*B1:B100)

Geht doch aber auch nicht, da die Kategorien ja unterschiedliche Anzahlen von Buchstaben haben! Was kann ich da machen?